Skripti http://oppe.admin.ut.ee/ained/tulemus/oppekava.asp kood

VÄRVIDE TÄHENDUSED
   Serveripoolne skript
   Kliendipoolne skript
   Link
   Include-lause
   Freimid
   Kommentaarid
   Objekti link
   HTML ja tavaline tekst


<%
'Tartu Ülikooli õppeaineregistri WWW-liides
'Autor: Aulis Sibola
'Juhendaja: Jaanus Pöial

'Õppekava/astme järgi ainete leidmine.
'Etteantud õppekava ja/või astme järgi leitakse ained ja väljastatakse
'nende nimekiri. Ained grupeeritakse õppekava, astme ja kohustuslikkuse
'järgi.
'Siit suundutakse konkreetse aine info juurde.
%>

<!--#INCLUDE  file="header.lisamine"-->
<!--#INCLUDE  file="eelmkontr.inc"-->
<%
'Kui soovitakse jooksva õppeaasta aineid, tuleb aastaarv arvutada:
if Request("selaastal") = "OK" then%>

<!--#INCLUDE  file="jooksevaasta.inc"-->
<%end if

otsityyp = Request("otsing")

'Ühenduse loomine:
Set yhendus = Server.CreateObject("ADODB.Connection")
'Andmebaasi avamine:
yhendus.Open "Aineregister"

'Astmete leidmine andmebaasist.
'Kui küsitakse õppekava aineid, on vaja väljastada kõikide astmete ained.
'Päringustring:
Paring = "select nimi, kirjapilt from DBA_Aste "
if otsityyp = "kavajaaste" or otsityyp = "aste" then
  Paring = Paring & "where nimi = '"  & Request("aste") & "' "
end if
Paring = Paring & "order by kood"

'Päring:
Set aste = yhendus.Execute(Paring)
%>

<html>
<head>
<title><%
if Request("tahestik") = "OK" then
%>
Ainete t&auml;hestikuline nimekiri<%
else
%>
Ainete nimekiri<%
end if
%>
</title>
</head>
<!--#INCLUDE  file="body.htm"-->
<center>
<h2><%
'Pealkiri.
if otsityyp = "aste" then
  if Request("kohus") = "koh" then
   Response.Write "Kohustuslikud ained"
  elseif Request("kohus") = "val" then
   Response.Write "Valikained"
  else
   Response.Write "Ained"
  end if
%>
, mis kuuluvad astmesse "<%=aste("kirjapilt")%>":<%
elseif otsityyp = "kavajaaste" then
%>
&Otilde;ppekava "<%=LCase(Request("oppekava"))%>  (<%=aste("kirjapilt")%>)" <%
  if Request("kohus") = "koh" then
   Response.Write "kohustuslikud ained:"
  elseif Request("kohus") = "val" then
   Response.Write "valikained:"
  else
   Response.Write "ained:"
  end if
else
%>
&Otilde;ppekava "<%=LCase(Request("oppekava"))%>" <%
  if Request("kohus") = "koh" then
   Response.Write "kohustuslikud ained:"
  elseif Request("kohus") = "val" then
   Response.Write "valikained:"
  else
   Response.Write "ained:"
  end if
end if
%>
</h2>
</center>
<%
'Leidmise kontroll:
eileidu = true


'Ainete leidmine:
do while not aste.EOF

  'Päringustrig:
  Paring = "select DBA_Aine.teaduskond, DBA_Aine.instituut, " & _
   "DBA_aine.oppetool, DBA_Aine.nr, DBA_aine.algoppeaasta, " & _
   "DBA_aine.loppoppeaasta, DBA_Tekst.nimi, " & _
   "Kuulajaskond.õppekava, Kuulajaskond.kohustus "
  if Request("tahestik") = "OK" then
   Paring = Paring & ", DBA_Tekst.sort "
  end if
  Paring = Paring & "from DBA_Aine, DBA_Tekst, Kuulajaskond "
  if Request("selaastal") = "OK" then
   Paring = Paring & ", DBA_ajakava "
  end if
  if Request("tahestik") <> "OK" then
   Paring = Paring & ", DBA_teaduskond "
  end if
  Paring = Paring & "where DBA_Aine.kood = DBA_Tekst.aine and " & _
   "DBA_Tekst.lõppaasta is Null and "
  if Request("selaastal") = "OK" then
   Paring = Paring & "DBA_Aine.kood = DBA_ajakava.aine and " & _
   "DBA_ajakava.aasta = " & JooksevAasta & " and "
  end if
  if Request("tahestik") <> "OK" then
   Paring = Paring & "DBA_aine.teaduskond = DBA_teaduskond.kood and "
  end if
  Paring = Paring & "DBA_Aine.kood = Kuulajaskond.aine and " & _
   "Kuulajaskond.aste = '"  & aste("nimi") & "' "
  if otsityyp = "kava" or otsityyp = "kavajaaste" then
   Paring = Paring & " and Kuulajaskond.õppekava = '"  & _
   Request("oppekava") & "' "
  end if
  if Request("kohus") = "koh" then
   Paring = Paring & " and Kuulajaskond.kohustus <> 0 "
  elseif Request("kohus") = "val" then
   Paring = Paring & " and Kuulajaskond.kohustus = 0 "
  end if
  if Request("selaastal") = "OK" then
   Paring = Paring & "group by Kuulajaskond.õppekava, Kuulajaskond.kohustus, DBA_Tekst.sort, DBA_Tekst.nimi, "
   if Request("tahestik") <> "OK" then
    Paring = Paring & "DBA_teaduskond.jarjestus, "
   end if
   Paring = Paring & "DBA_aine.teaduskond, " & _
   "DBA_aine.instituut, DBA_aine.oppetool, DBA_aine.nr, " & _
   "DBA_aine.algoppeaasta, DBA_aine.loppoppeaasta "
  end if
  if Request("tahestik") = "OK" then
   Paring = Paring & "order by Kuulajaskond.õppekava, Kuulajaskond.kohustus, " & _
   "DBA_Tekst.sort, DBA_aine.teaduskond, " & _
   "DBA_aine.instituut, DBA_aine.oppetool, DBA_aine.nr"
  else
   Paring = Paring & "order by Kuulajaskond.õppekava, Kuulajaskond.kohustus, " & _
   "DBA_teaduskond.jarjestus, " & _
   "DBA_aine.instituut, DBA_aine.oppetool, DBA_aine.nr"
  end if

  'Päring:
  Set ained = yhendus.Execute(Paring)

  if otsityyp = "kava" then
   if not ained.EOF then
    if eileidu then
     if Request("selaastal") <> "OK" then
%>

<form action=oppekava.asp method=POST>
<input type=hidden name=oppekava value='<%=Request("oppekava")%>'>
<input type=hidden name=aste value=<%=Request("aste")%>>
<input type=hidden name=otsing value=<%=Request("otsing")%>>
<input type=hidden name=kohus value=<%=Request("kohus")%>>
<input type=hidden name=tahestik value=<%=Request("tahestik")%>>
<input type=hidden name=selaastal value=OK>
<input type=submit value="Jätta alles sel õppeaastal loetavad ained">
</form>
<%
     end if
     eileidu = false
    end if
%>

<b><%=aste("kirjapilt")%>:</b>
<ul>
<%end if
  end if
 
  eelmkava = "Täiesti vale kava"
  eelmkoh = 5
  esimkava = true
  kavavah = true

  kontroll = false

  do while not ained.EOF

   kontroll = true

   if eileidu then
    if Request("selaastal") <> "OK" then
%>

<form action=oppekava.asp method=POST>
<input type=hidden name=oppekava value='<%=Request("oppekava")%>'>
<input type=hidden name=aste value=<%=Request("aste")%>>
<input type=hidden name=otsing value=<%=Request("otsing")%>>
<input type=hidden name=kohus value=<%=Request("kohus")%>>
<input type=hidden name=tahestik value=<%=Request("tahestik")%>>
<input type=hidden name=selaastal value=OK>
<input type=submit value="Jätta alles sel õppeaastal loetavad ained">
</form>
<%
    end if
    eileidu = false
   end if
   if IsNull(ained("õppekava")) then
    oppekava = "K&otilde;ikides &otilde;ppekavades"
   else
    oppekava = ained("õppekava")
   end if

   if eelmkava <> oppekava then
    eelmkava = oppekava
    eelmkoh = 5
    kavavah = true

    if esimkava then
     esimkava = false
    else
     Response.Write "</table>" & vbNewLine
     if Request("kohus") = "molemad" then
      Response.Write "</ul>" & vbNewLine
     end if
     if otsityyp = "aste" then
      Response.Write "</ul>" & vbNewLine
     end if
    end if

    if otsityyp = "aste" then
     Response.Write "<b>" & oppekava & ":</b>" & _
   vbNewLine & "<ul>" & vbNewLine
    end if
   end if

   if eelmkoh <> ained("kohustus") then
    eelmkoh = ained("kohustus")

    if kavavah then
     kavavah = false
    else
     Response.Write "</table>" & vbNewLine
     if Request("kohus") = "molemad" then
      Response.Write "</ul>" & vbNewLine
     end if
    end if

    if Request("kohus") = "molemad" then
     Response.Write "<i>"
     if ained("kohustus") = 0 then
      Response.Write "Valikained:"
     else
      Response.Write "Kohustuslikud ained:"
     end if
     Response.Write "</i>" & vbNewLine & "<ul>" & vbNewLine
    end if
    Response.Write "<table>" & vbNewLine
   end if

  'Aine väljastus:
%>
<tr>
  <td><%=ained("teaduskond")&ained("instituut")&"."&ained("oppetool")&"."&ained("nr")%></td><%
if IsNull(ained("nimi")) then
%>
  <td><a href=aine.asp?<%=ained("teaduskond")&ained("instituut")&"."&ained("oppetool")&"."&ained("nr")%>>__</a><%
else
%>
<td><a href=aine.asp?<%=ained("teaduskond")&ained("instituut")&"."&ained("oppetool")&"."&ained("nr")%>><%=ained("nimi")%></a><%
end if
if Not(IsNull(ained("loppoppeaasta"))) then
    if ained("algoppeaasta") = ained("loppoppeaasta") then
     Response.Write " (&uuml;hekordne aine " & ained("algoppeaasta") & "/"
     Response.Write ained("algoppeaasta") + 1 & " &otilde;a.)"
    else
     Response.Write " (l&otilde;petatud " & ained("loppoppeaasta") & " a.)"
    end if
   end if%>
</td>
</tr>
<%
   ained.MoveNext
  loop 'Ained

  'Ainete sulgemine:
  ained.close

  if kontroll then%>

</table>
</ul>
</ul>
<%end if
  if otsityyp = "kava" then
   if not kavavah then%>

</ul>
<%end if
  end if

  aste.MoveNext

Loop 'Astmete tsükkel

'Korralik sulgemine:
aste.close
yhendus.close

if eileidu then
%>

<h3>Ained puuduvad...</h3>
<%
end if
%>

<!--#INCLUDE  file="footer.htm"-->