Skripti http://oppe.admin.ut.ee/ained/tulemus/toimumisfunc.inc kood

VÄRVIDE TÄHENDUSED
   Serveripoolne skript
   Kliendipoolne skript
   Link
   Include-lause
   Freimid
   Kommentaarid
   Objekti link
   HTML ja tavaline tekst


<%
'Tartu Ülikooli õppeaineregistri WWW-liides
'Autor: Aulis Sibola
'Juhendaja: Jaanus Pöial

'Õppeaine ajakava väljastuseks vajalike funktsioonide definitsioonid.

'Määrab toimumiskavas lõpetuse vormi (eksam, arvestus)
'Argumentideks on eksamite ja arvestuste arvud.
'Tagastab kujul "=> arvE arvA"
Function loppexam(ex, ar)

'Eksam:
If ex > 1 Then
  exa = ex & "E "
ElseIf ex = 1 Then
  exa = "E "
Else
  exa = ""
End If

'Arvestus:
If ar > 1 Then
  arv = ar & "A"
ElseIf ar = 1 Then
  arv = "A"
Else
  arv = ""
End If

'Tulemuse tagastamine:
If ex <> 0 Or ar <> 0 Then
  loppexam = "&nbsp;&nbsp;=> " & exa & arv
Else
  loppexam = ""
End If

End Function 'eksam/arvestus

'Kontrolltöid, referaate õigel kujul
'Argumentideks on kontrolltööde ja referaatide arvud.
'Tagastab kujul "arv knt, arv ref" või "arv knt" või "arv ref".
Function kontroll(knt, ref)

If knt <> 0 And ref <> 0 Then
  kontroll = knt & " knt, " & ref & " ref"
ElseIf knt <> 0 Then
  kontroll = knt & " knt"
ElseIf ref <> 0 Then
  kontroll = ref & " ref"
Else
  kontroll = ""
End If

End Function 'kontrolltöid/referaate

'Nädalas loenguid, praktikume, seminare
'Argumentideks saab loengute, praktikumide, seminaride arvud ja märke
'praktikumi või seminari kohustuslikkuse kohta.
'Tagastab kujul "arvL, arvP, arvS n-s" kohustuslikkuse korral tehakse
'vastav element esiletõstetult (bold).
Function nadal(loe, pra, sem, prkoh, sekoh)

'Praktikum kohustuslik?
If prkoh = 0 Then
  alprax = ""
  loprax = ""
Else
  alprax = "<b>"
  loprax = "</b>"
End If

'Seminar kohustuslik?
If sekoh = 0 Then
  alsem = ""
  losem = ""
Else
  alsem = "<b>"
  losem = "</b>"
End If

'loengutunnid:
If loe <> 0 Then
  If pra <> 0 Or sem <> 0 Then
   str = loe & " L, "
  Else
   str = loe & " L n-s"
  End If
Else
  str = ""
End If

'praktikumitunnid:
If pra <> 0 Then
  If sem <> 0 Then
   str = str & alprax & pra & " P" & loprax & ", "
  Else
   str = str & alprax & pra & " P" & loprax & " n-s"
  End If
End If

'seminaritunnid:
If sem <> 0 Then
  str = str & alsem & sem & " S" & losem & " n-s"
End If

nadal = str

End Function 'loengud/praktikumid/seminarid nädalas

'Korduva aine korral toimumiskava väljastus
'Argument: nädalate arv.
'Tagastab kujul "korduv: arv"
Function korduv(nr)

If nr = 0 Then
  korduv = "korduv"
Else
  korduv = "korduv: " & nr & " n."
End If

End Function 'korduv aine

'Konkreetse toimumiskavata aine korral toimumiskava väljastus
'Argumentideks saab kuu (numbrina) ja nädalate arvu.
'Tagastab kujul: "kuu, nädal"
Function kuu(nr, teine)

'Kui pole määratud:
If nr = 0 And teine = 0 Then
  kuu = "Ei ole teada"
  Exit Function
End If

'Kas nädalad on antud (>0)?
If teine = 0 Then
  mitunadal = ""
Else
  mitunadal = teine
End If

'Kuu määratlemine:
If nr = 1 Then
  kuu = "jaanuar, " & mitunadal
  Exit Function
End If
If nr = 2 Then
  kuu = "veebruar, " & mitunadal
  Exit Function
End If
If nr = 3 Then
  kuu = "m&auml;rts, " & mitunadal
  Exit Function
End If
If nr = 4 Then
  kuu = "aprill, " & mitunadal
  Exit Function
End If
If nr = 5 Then
  kuu = "mai, " & mitunadal
  Exit Function
End If
If nr = 6 Then
  kuu = "juuni, " & mitunadal
  Exit Function
End If
If nr = 7 Then
  kuu = "juuli, " & mitunadal
  Exit Function
End If
If nr = 8 Then
  kuu = "august, " & mitunadal
  Exit Function
End If
If nr = 9 Then
  kuu = "september, " & mitunadal
  Exit Function
End If
If nr = 10 Then
  kuu = "oktoober, " & mitunadal
  Exit Function
End If
If nr = 11 Then
  kuu = "november, " & mitunadal
  Exit Function
End If
If nr = 12 Then
  kuu = "detsember, " & mitunadal
  Exit Function
End If

'Kui kuud pole antud (=0):
If mitunadal <  10 Then
  kuu = " " & mitunadal
Else
  kuu = mitunadal
End If

End Function 'umbes ajakava

'Tavalise aine korral toimumiskava väljastus
'Argumentideks saab alg ja lõppnädala.
'Tagastab kujul "alg. - lõpp. n"
Function nadalad(alg, lopp)

'Kui pole määratud:
If alg = 0 And lopp = 0 Then
  nadalad = "Ei ole teada"
  Exit Function
End If

'Kui kestab ühe nädala (määratud kas algusega või lõpuga):
If alg = 0 Then
  nadalad = lopp & ". n."
  Exit Function
End If
If lopp = 0 Then
  nadalad = alg & ". n."
  Exit Function
End If

'Antud on nii algus kui lõpp:
nadalad = alg & ". - " & lopp & ". n."

End Function 'tavaline aine

%>